// PoVRay 3.7 Scene File "xodbb2.pov"
// author: dookie x
// date:   02.27.2018
//--------------------------------------------------------------------------
#version 3.7;
global_settings{ assumed_gamma 1.0 }
#default{ finish{ ambient 0.1 diffuse 0.9 }} 
//--------------------------------------------------------------------------
#include "colors.inc"
#include "textures.inc"
#include "glass.inc"
#include "metals.inc"
#include "golds.inc"
#include "stones.inc"
#include "woods.inc"
#include "shapes.inc"
#include "shapes2.inc"  
#include "onetire2.pov"  
#include "skullobj.pov"

//--------------------------------------------------------------------------
// camera ------------------------------------------------------------------
#declare Camera_0 = camera {perspective angle 75               // front view
                            location  <0.0 , 7.0 ,-20.0>
                            right     x*image_width/image_height
                            sky -y
                            look_at   <0.0 , 7.0 , 0.0>}

camera{Camera_0}
// sun ----------------------------------------------------------------------
light_source{< 30,30,-30> color White}
//background{          color rgb< 0.45, 0.0, 0.2> } //   very dark red  
               
                  // end of texture  
                  // bkgd

// ground -------------------------------------------------------------------
   
plane{ <0,1,0>, 0 
       texture{ pigment{ checker color rgb<1,.1,.1> color rgb<0.25,0.15,0.1>*0}
              //normal { bumps 0.75 scale 0.025}
                finish { phong 0.1}
              } // end of texture  
              translate y *-10
     } // end of plane 
       
       

#declare TripSpike=union{prism {
    conic_sweep
    linear_spline
    0.3, // sweep the following shape from here ...
    3, // ... up through here
    5, // the number of points making up the shape ...
    < .2, .2>, < .2,-.2>, <-.2,-.2>, <-.2,.2>, <.2, .2>
    texture { Polished_Chrome}
  }          
  sphere{<0,3.2,0>,.25}     texture { Polished_Chrome}}
  
#declare MetalCross=
union{  
  object {TripSpike}
  object {TripSpike rotate z*90}    
  object {TripSpike rotate z*-90} 
  object {TripSpike scale y*2 rotate z*180}   
  sphere { <0,0,0>, 0.69 texture { Polished_Chrome } }
  torus { 1.05,0.2 texture { Polished_Chrome} rotate<90,0,0>}
  
   torus { .6,0.1 texture { Polished_Chrome} translate y*-6.2} 
    torus { .65,0.1 texture { Polished_Chrome} translate y*-6.4} 
     torus { .7,0.1 texture { Polished_Chrome} translate y*-6.6}    
}

object{MetalCross translate y*12}

#declare Heart=union{
#declare Strength = 1.1; //(+ or -) strength of component's radiating density
#declare Radius1  = .95; //(0 < Radius) outer sphere of influence on other components
blob{
  threshold 0.6 // threshold (0.0 < threshold <= Strength) surface falloff threshold #
  sphere{<-0.52,  .15,   0>, Radius1, Strength scale <1,1.2,.9>}
  sphere{< 0.53,  .15,   0>, Radius1, Strength scale <1,1.2,.9>}
  sphere{<0,-0.55,0>, Radius1, Strength scale z*.95}   
  sphere{<0,0.55,0>, Radius1/2, Strength scale z*.95}
  scale 1
  rotate<30,0,0>
  translate<0,1.0,-0.3>
  texture{ pigment{ color rgb<.2,0.0,0.05> }
           finish { phong .5 }    // ooh shiny shiny!
         }
 } //------------------------------------------------------ end of blob 
 
               }

object{Heart scale 3.37 translate y*-.5}      


#declare SF = array[7] {.7,.8,.65,.75,.6,.7,.8} 
#declare TV = array[7] {<.1,.1,0>,<0,-.1,0>,<-.1,.05,0>,<.2,-.2,0>,<-.05,.3,0>,<.2,-.1,0>,<-.15,-.25,0>}        
#declare Looper=-3; 
#while (Looper< 4) 
#declare tyreIndex=Looper+3;
   object {ThornyTire2 scale SF[tyreIndex]*.8 
                    rotate x*90                //she's been layin' down!  stand'er up!! 
                    rotate y*Looper*-5         // flat-faced in the middle, turning to the edge...
                    translate <Looper/1.27,3.5,-4> 
                    translate TV[tyreIndex]
                    } 
 
 #declare Looper=Looper+1;
 #end
 
 #declare Looper=0;
   #while (Looper<6)
          object{SkullNTeeth scale .69 rotate x*180 rotate z*180 translate<0,6.0,-.49> rotate y*Looper*60}   
          #declare Looper=Looper+1;
       #end