// Persistence Of Vision raytracer version 3.0 styling file.
// a buncha cylinders, some torii, and a cylinder-Tallbike-001
//first made a long long time ago, updated for individual componentry
//starting  05.16.07
global_settings { assumed_gamma 2.2 }
#include "colors.inc"
#include "textures.inc"
#include "metals.inc"
#include "finish.inc"  
#include "onetireb.pov"

#declare MyChrome = texture {NotAsShinyTex}
     
camera {
    //rotate 360*clock*x      //the magical rotate! hopefully!
    location <27, -87, 0>
    sky x
    look_at <27,0,0>  
    right     x*image_width/image_height
    }  
    
light_source { <30,    -3,  6> White }
light_source { <20,  -4,15> White }
light_source { <-5,1.7,-10> White }
light_source { <20,5,-27> White }
light_source { <35,0,-20> White}
light_source { <30, -30,1> White}
light_source { <55,1,1> White }
light_source
{
  0*x                     // light's position (translated below)
  color rgb <1,1,1>       // light's color
  spotlight               // this kind of light source
  translate <60, 1,-10> // <x y z> position of light
  point_at <0, -5, -10>      // direction of spotlight
  radius 10                // hotspot (inner, in degrees)
  tightness 15            // tightness of falloff (1...100) lower is softer, higher is tighter
  falloff 25               // intensity falloff radius (outer, in degrees)
}   


/*sky_sphere{pigment{gradient x
                   color_map {[0.000 0.002 color rgb <1.0, 0.2, 0.0>
                                           color rgb <1.0, 0.2, 0.0>]
                              [0.002 0.200 color rgb <0.8, 0.1, 0.0>
                                           color rgb <0.2, 0.2, 0.3>]}
                   scale 2
                   translate -1}  
           pigment{bozo
                   turbulence 0.65
                   octaves 6
                   omega 0.7
                   lambda 2
                   color_map {[0.0 0.1 color rgb <0.85, 0.85, 0.85>
                                       color rgb <0.75, 0.75, 0.75>]
                              [0.1 0.5 color rgb <0.75, 0.75, 0.75>
                                       color rgbt <1, 1, 1, 1>]
                              [0.5 1.0 color rgbt <1, 1, 1, 1>
                                       color rgbt <1, 1, 1, 1>]}
            scale <0.2, 1.5, 0.5>}
   rotate -x*clock*360}  
*/    

#declare ChequereDisc=disc {<0,0,0>,x,9                  //ooh! checkered disc! - this was long ago...
      pigment {checker Red,Blue}
      translate <-14,0,0>
      scale <1,7,7>
      finish {ambient .4 specular .2}
      }


//background { color rgb <.6, .3, .6> }
#declare TyrePair= union{torus{13.5,.5 
                           pigment {color Black}}
                         torus {13.5,.5
                           translate <0,0,42.75>
                           pigment {color Black}}}  

#declare TyrePair= union{object{ThornyTire rotate y*180 scale 10} 
                         object{ThornyTire rotate y*180 scale 10 translate <0,0,42.75>}}
#declare BottomFrame=union{
cylinder {<0,-2,0>, < -2.5,-1.5,17.25>,.3 }  //seatstay
cylinder {<0,2,0>, <-2.5,1.5,17.25>,.35 }  //and the other
cylinder {<0,2,0>, <21,1,10.5>,.35}    //seatstaze
cylinder  {<0,-2,0>,  <21,-1,10.5>,.35}
cylinder  {<-2.5,-2,17.25>,<-2.5,2,17.25>,.95}  // bottom cranx
cylinder {<-2.5,0,17.25>,<16,0,36.5>,.60}  //bottom tube
cylinder {<-2.5,0,17.25>,<25,0,9>,.6}  //seat tube/post
cylinder {<21.5,0,10>,<21.5,0,35.0>,.6} // top tube
cylinder {<15.4125,0,36.875>,<23.25,0,34.5>,.65}  //bottom steer tube, oy the math!
cylinder {<15,1,37>,<5,1.5,40>,.35} // top of fork
cylinder {<15,-1,37>,<5,-1.5,40>,.35} 
cylinder {<5,1.5,40>,<0,2,42.75>,.3}
cylinder {<5,-1.5,40>,<0,-2,42.75>,.3}  //bottom of fork }
}//end BottomFrame
#declare MagicWand=cylinder {<15,0,37>,<46.35,0,27.5>,.5 texture {MyChrome}}  // steer stem
#declare SeatPostTop=cylinder {<45,0,6>,<41,0,7>,.5 texture {MyChrome}}  //seatpost
#declare Bars=union{cylinder {<48,0,27>,<50,3.5,32>,.4}
                    cylinder {<48,0,27>,<50,-3.5,32>,.4}            // bars
                    cylinder {<50,3.5,32>,<50,-3.5,32>,.5}
                    cylinder {<50,3.5,32>,<51.5,14,30.5>,.5}
                    cylinder {<50,-3.5,32>,<51.5,-14,30.5>,.5}
                    cylinder {<48,0,27>,<46.35,0,27.5>,.4}
                    texture { MyChrome }} 
#declare TopFrame=union{cylinder {<44.7,0,28>,<38.1,0,30>,.65} //top steer tube
                        cylinder {<38.1,0,30>,<34.8,-2,31>,.55}
                        cylinder {<38.1,0,30>,<34.8,2,31>,.55}    // forklets
                        cylinder {<23,-1.8,11.5>,<23,1.8,11.5>,1} //top bb
                        cylinder {<23, 0,11.5>,<39,0,29.5>,.6} //top bottom tube
                        cylinder {<23,0,11.5>,<41,0,7>,.6} //top seat tube/post
                        cylinder {<34,0,9>,<43,0,28.5>,.6}//top top tube}
                        }//end topframe     
#declare CrappySeat=union{prism {
  linear_sweep
  linear_spline // linear_spline | quadratic_spline | cubic_spline
  -.8,         // height 1
   1,           // h2
  10,           // #-o-pts
  < 0, 0>, < 2,  0.5>, < 4, 1>, <1.5, 5.5>, < 1,9>,          // all this for a crappy seat
  <-1,9>, <-1.5,5.5>, <-4, 1>, <-2,  0.5>,<0,0>
  rotate z*90
  rotate y*3       // tilt it up a teensy bit
  translate <46,0,3>
  pigment {color Black}
}}//end seat    
#declare Pedals=union{box{<27.5, 3, 4.5><28.5,7,  7.5>}
                       box{<17.5,-3,15>,<18.5,-7,18>}
                       pigment {Black}}       
#declare Cranx=union{disc{<23,-2,11.5>,y,3.3,2.6 }                // top cranx gear
                     cylinder{<23,-2,11.5>,<18,-3,16.5>,.3 }
                     cylinder {<23,2,11.5>,<28,3,6>,.3}            // and cranx
                     texture { MyChrome }}
                        
#declare Tallbike001 =      // I do declare...
  union{object{TyrePair}  
        object{BottomFrame pigment{Yellow/2}}
        object{TopFrame pigment{Yellow/2}} 
        object{MagicWand texture{MyChrome}} 
        object{SeatPostTop}
        object{TyrePair}
        object{Bars} 
        object{CrappySeat}    
        object{Pedals} 
        object{Cranx}
        } //end Tallbike union
  
object {Tallbike001 
         rotate x*180
         rotate z*15
         translate z*50
         
}  

//object {BlueSkies}